João Mello

library DllEntry;
 
uses
  SysUtils,
  Windows,
  Dialogs,
  Classes;
 
procedure DLLEntryPoint(dwReasson: DWord);
begin
  case dwReasson of
    DLL_PROCESS_ATTACH: ShowMessage('Anexando ao processo');
    DLL_PROCESS_DETACH: ShowMessage('Desanexando do processo');
    DLL_THREAD_ATTACH : MessageBeep(0);
    DLL_THREAD_DETACH : MessageBeep(0);
  end;
end;
 
begin
  { Primeirto, atribui o procedimento à variável DLLProc }
  DllProc := @DLLEntryPoint;
  { Agora, chama o procedimento apra refletir se a DLL está anexada ao processo }
  DLLEntryPoint(DLL_PROCESS_ATTACH);
end.

unit ufrmPrincipal;
 
interface
 
uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;
 
type
  TTestThread = class(TThread)
    procedure Execute; override;
    procedure SetCaptionData;
  end;
 
  TfrmPrincipal = class(TForm)
    btnLoadLibrary: TButton;
    btnFreeLibrary: TButton;
    btnCreateThread: TButton;
    btnFreeThread: TButton;
    Label1: TLabel;
    lblCount: TLabel;
    procedure btnLoadLibraryClick(Sender: TObject);
    procedure btnFreeLibraryClick(Sender: TObject);
    procedure FormCreate(Sender: TObject);
    procedure btnCreateThreadClick(Sender: TObject);
    procedure btnFreeThreadClick(Sender: TObject);
  private
    LibHandle : THandle;
    TestThread: TTestThread;
    Counter   : Integer;
    GoThread  : Boolean;
  end;
 
var
  frmPrincipal: TfrmPrincipal;
 
implementation
 
{$R *.dfm}
 
{ TTestThread }
 
procedure TTestThread.Execute;
begin
  while frmPrincipal.GoThread do
  begin
    Synchronize(SetCaptionData);
    Inc(frmPrincipal.Counter);
  end;
end;
 
procedure TTestThread.SetCaptionData;
begin
  frmPrincipal.lblCount.Caption := IntToStr(frmPrincipal.Counter);
end;
 
procedure TfrmPrincipal.btnCreateThreadClick(Sender: TObject);
{ Este procedimento cria a instância da TThread. Se a DLL for carregada,
  ocorrerá um bipe de mensagem. }
begin
  if not Assigned(TestThread) then
  begin
    GoThread := True;
    TestThread := TTestThread.Create(False);
  end;
end;
 
procedure TfrmPrincipal.btnFreeLibraryClick(Sender: TObject);
{ Este procedimento libera a biblioteca }
begin
  if not (LibHandle = 0) then
  begin
    FreeLibrary(LibHandle);
    LibHandle := 0;
  end;
end;
 
procedure TfrmPrincipal.btnFreeThreadClick(Sender: TObject);
{ Na liberação da TThread, um bipe de mensagem ocorrerá, se a DLL for carregada. }
begin
  if Assigned(TestThread) then
  begin
    GoThread := False;
 
    while TestThread.Suspended do
      TestThread.Resume;
 
    TestThread.WaitFor;
 
    FreeAndNil(TestThread);
 
    Counter := 0;
  end;
end;
 
procedure TfrmPrincipal.btnLoadLibraryClick(Sender: TObject);
{ Este procedimento carrega a biblioteca DllEntryLib.dll }
begin
  if LibHandle = 0 then
  begin
    LibHandle := LoadLibrary('DllEntry.dll');
    if LibHandle = 0 then
      raise Exception.Create('Erro no carregar DLL');
  end else
  begin
    MessageDlg('DLL ja carregada!', mtWarning, [mbOK], 0);
  end;
end;
 
procedure TfrmPrincipal.FormCreate(Sender: TObject);
begin
  LibHandle  := 0;
  TestThread := nil;
end;
 
end.